Question Comment changer la langue de toutes les diapositives PowerPoint à la fois?


Je veux changer la langue de vérification de toutes mes diapositives dans un Powerpoint. J'ai essayé de définir la langue via le menu Language Preferences, mais cela ne change que pour les nouveaux powerpoints.


127
2018-06-04 10:01


origine


Duplicata possible de Changer la langue de vérification orthographique sur une présentation PowerPoint - sancho.s
Il semble que la nouvelle version de PowerPoint soit particulièrement boguée à cet égard. J'ai une zone de texte où j'ai changé la langue de tout le texte en langue A. (La langue par défaut est B.) Donc, quand je commence à taper dans cette zone de texte, la langue change automatiquement en B. la langue aide (après avoir tout essayé) mais non. Maintenant, la langue par défaut est A, la langue de tous les autres textes dans la zone de texte est A (et j'ai redémarré PP) mais tout le nouveau texte apparaît toujours comme B. Donc, ma seule question est: tout à fait? - lebatsnok
Oui, il existe un moyen de désactiver la vérification orthographique: support.microsoft.com/en-us/help/937422/... - résolu mon problème! - lebatsnok


Réponses:


Je sais qu'une réponse a déjà été acceptée, mais cela ne change que la langue de vérification d'un unique zone de texte, et vous oblige à les modifier tous manuellement.

Changer la langue du tout PowerPoint facilement, ouvrez le Vue onglet et sélectionnez le Contour vue.

Maintenant, appuyez sur

  • Ctrl+UNE pour tout sélectionner.
  • Outils → La langue → Choisissez votre langue à définir.

De même, alors que vous avez tout sélectionné, vous pouvez changer d'autres choses comme les polices, les couleurs, etc. Bien que dans bien des cas, il soit préférable de changer le masque des diapositives, de nombreux éditeurs peuvent avoir beaucoup de formatage s'écarte du maître sous-jacent et doit être réinitialisé pour être cohérent. Vous pouvez également réinitialiser les diapositives individuelles au style maître, mais cela peut entraîner le déplacement d'espaces réservés, ce qui peut être indésirable dans certaines situations.

PowerPoint 2013

  • Vue → Contour → sélectionnez toutes les diapositives (dans un menu de gauche) via Ctrl+UNE.
  • La revue → La langue → Définir la langue de vérification ... → Choisissez votre langue à définir.

Quant à moi - PowerPoint redémarrer était nécessaire. Probablement parce que j'ai aussi changé Modification de la langue:

  • La revue → La langue → Définir la langue de vérification ... → Préférences linguistiques → Choisissez les langues d'édition.

143
2018-03-17 17:29



Merci pour la réponse, mais après avoir changé la langue, le texte nouvellement tapé est toujours dans la langue précédente (celle par défaut). De plus, si vous accédez aux diapositives principales, sélectionnez la glissière, vous remarquerez que la langue dans la barre de langue est toujours la langue par défaut et que le menu pour la modifier est grisé. Je suis en train de devenir fou que Microsoft n'ait pas résolu ce problème depuis tant d'années. - Endrju
Impressionnant! Bien que ce ne soit pas parfait, cela aide certainement. Je suis d'accord avec @Endrju, pourquoi n'est-ce pas encore réglé ?! - Mike
Pour l'enregistrement, dans Office 2013, le menu Langue se trouve dans le volet Révision (Définir la langue de vérification) - Maria Ines Parnisari
Powerpoint est tout simplement terrible, n'est-ce pas? En fait, le bureau ouvert me manque quand j'ai des problèmes comme celui-ci. Je serai de retour au bureau dès qu'ils prendront en charge la sauvegarde d'une vidéo. - mjaggard
@Endrju Vous devez changer la langue pour PowerPoint dans la barre des tâches Windows pour que le nouveau type de texte soit dans la nouvelle langue. Voir les détails dans ma réponse. Cela m'a beaucoup énervé pendant si longtemps ... - Gas


En utilisant Powerpoint 2010 J'ai ouvert le menu Outline -

outline tab

Sélectionne tout le texte (Ctrl + A), ouvre le menu de langue et définit ma langue de vérification

language option

Et ça a marché!

Le menu de langue se trouve dans l'onglet Ruban de révision (après l'onglet Diaporama et non visible sur la capture d'écran).


34
2018-06-04 10:01



Ne fonctionne que pour une seule diapositive - Helge Klein
Cela fonctionne pour les dispositions de base des diapositives. Cela ne changera pas la langue du texte à l'intérieur des zones de texte ou imbriqué dans d'autres formes. - Duncan Jones
Fonctionne également sur Office 2007. - Alfredo Osorio
Travaillé sur Office Mac aussi. - Jim McKeeth


Les réponses existantes fonctionnent pour le texte présent dans le contour. Malheureusement, dans mon cas, cela ne couvrait pas une partie importante du texte, y compris les chiffres, les tableaux, etc.

Cette macro a résolu le problème pour moi:

 Sub ChangeProofingLanguageToEnglish()
    Dim j, k, m, scount, fcount, gcount As Integer
    scount = ActivePresentation.Slides.Count
    For j = 1 To scount
        fcount = ActivePresentation.Slides(j).Shapes.Count
        For k = 1 To fcount
            If ActivePresentation.Slides(j).Shapes(k).HasTextFrame Then
                ActivePresentation.Slides(j).Shapes(k) _
                .TextFrame.TextRange.LanguageID = msoLanguageIDEnglishUS
            End If
            If ActivePresentation.Slides(j).Shapes(k).Type = msoGroup Then
                gcount = ActivePresentation.Slides(j).Shapes(k).GroupItems.Count
                For m = 1 To gcount
                    If ActivePresentation.Slides(j).Shapes(k).GroupItems.Item(m).HasTextFrame Then
                    ActivePresentation.Slides(j).Shapes(k).GroupItems.Item(m) _
                    .TextFrame.TextRange.LanguageID = msoLanguageIDEnglishUS
            End If
                Next m
            End If
        Next k
    Next j
End Sub

Le "msoLanguageIDEnglishUS" utilisé dans la macro ci-dessus peut être remplacé par n'importe quelle langue. La liste complète des langues se trouve dans Cet article

(Le crédit va à Ganesh Kumar qui a posté la macro originale ici. J'ai ajouté un support pour le premier niveau de regroupement de formes. Pour l'améliorer encore, la macro peut être récursive pour rechercher des groupes contenant d'autres groupes, etc.)


18
2017-08-09 08:11



+1 Bon début Voir ma réponse pour une version entièrement récursive basée sur cette réponse. - Duncan Jones


J'ai amélioré La réponse d'Inigo fournir une version récursive qui modifie tous les éléments dans la langue souhaitée.

Cette version examinera récursivement chaque forme qui est un type de groupe. Certaines expériences suggèrent que msoGroup et msoSmartArt sont les types de groupe - n'hésitez pas à ajouter à cette liste si vous trouvez que d'autres types de formes peuvent contenir des objets texte.

Sub ChangeProofingLanguageToEnglish()
    Dim j, k As Integer
    Dim languageID As MsoLanguageID

    'Set this to your preferred language
    languageID = msoLanguageIDEnglishUK

    For j = 1 To ActivePresentation.Slides.Count
        For k = 1 To ActivePresentation.Slides(j).Shapes.Count
            ChangeAllSubShapes ActivePresentation.Slides(j).Shapes(k), _
              languageID
        Next k
    Next j
End Sub


Sub ChangeAllSubShapes(targetShape As shape, languageID As MsoLanguageID)
    Dim i As Integer

    If targetShape.HasTextFrame Then
        targetShape.TextFrame.TextRange.languageID = languageID
    End If

    Select Case targetShape.Type
        Case msoGroup, msoSmartArt
            For i = 1 To targetShape.GroupItems.Count
                ChangeAllSubShapes targetShape.GroupItems.Item(i), languageID
            Next i
    End Select
End Sub

16
2017-11-25 09:52



Lorsque je l'exécute dans PowerPoint 16.10 sur OSX, j'obtiens: Compile error: Method or data member not found - Etienne Low-Décarie


Basé sur les réponses d'Inigo, Duncan, Maria et DomDev, cela fonctionne pour les formes, les tableaux, les groupes, SmartArt, maintenant et dans le futur:

Sub ChangeProofingLanguageToFrench()
    Dim j, k As Integer
    Dim languageID As MsoLanguageID

    'Set this to your preferred language
    languageID = msoLanguageIDFrench

    'Loop all the slides in the document, and change the language
    For j = 1 To ActivePresentation.Slides.Count
        For k = 1 To ActivePresentation.Slides(j).Shapes.Count
            ChangeAllSubShapes ActivePresentation.Slides(j).Shapes(k), languageID
        Next k
    Next j

    'Loop all the master slides, and change the language
    For j = 1 To ActivePresentation.SlideMaster.CustomLayouts.Count
        For k = 1 To ActivePresentation.SlideMaster.CustomLayouts(j).Shapes.Count
            ChangeAllSubShapes ActivePresentation.SlideMaster.CustomLayouts(j).Shapes(k), languageID
        Next k
    Next j

    'Change the default presentation language, so that all new slides respect the new language
    ActivePresentation.DefaultLanguageID = languageID
End Sub

Sub ChangeAllSubShapes(targetShape As Shape, languageID As MsoLanguageID)
    Dim i As Integer, r As Integer, c As Integer

    If targetShape.HasTextFrame Then
        targetShape.TextFrame.TextRange.languageID = languageID
    End If

    If targetShape.HasTable Then
        For r = 1 To targetShape.Table.Rows.Count
            For c = 1 To targetShape.Table.Columns.Count
                targetShape.Table.Cell(r, c).Shape.TextFrame.TextRange.languageID = languageID
            Next
        Next
    End If

    Select Case targetShape.Type
        Case msoGroup, msoSmartArt
            For i = 1 To targetShape.GroupItems.Count
                ChangeAllSubShapes targetShape.GroupItems.Item(i), languageID
            Next i
    End Select
End Sub

7
2017-07-09 09:41



En ce qui concerne les autres solutions, lorsque je lance ceci dans PowerPoint 16.10 sur OSX, je reçois: Compile error: Method or data member not found. Des solutions suggérées? Il semble mettre en évidence .DefaultLanguageID. - Etienne Low-Décarie
@ EtienneLow-Décarie: L'API pourrait avoir changé dans PowerPoint 16; Je ne l'ai pas donc je ne peux pas vérifier, désolé. - tricasse


La version de Duncan fonctionne bien pour tout sauf les tables. J'ai trouvé un autre code qui semble aussi fonctionner avec des tableaux: https://stackoverflow.com/questions/4735765/powerpoint-2007-set-language-on-tables-charts-etc-that-contains-text 

Public Sub changeLanguage()
    On Error Resume Next
    Dim gi As GroupShapes '<-this was added. used below
    'lang = "English"
    lang = "Norwegian"
    'Determine language selected
    If lang = "English" Then
        lang = msoLanguageIDEnglishUK
    ElseIf lang = "Norwegian" Then
        lang = msoLanguageIDNorwegianBokmol
    End If
    'Set default language in application
    ActivePresentation.DefaultLanguageID = lang

    'Set language in each textbox in each slide
    For Each oSlide In ActivePresentation.Slides
        Dim oShape As Shape
        For Each oShape In oSlide.Shapes
            'Check first if it is a table
            If oShape.HasTable Then
                For r = 1 To oShape.Table.Rows.Count
                    For c = 1 To oShape.Table.Columns.Count
                    oShape.Table.Cell(r, c).Shape.TextFrame.TextRange.LanguageID = lang
                    Next
                Next
            Else
                Set gi = oShape.GroupItems
                'Check if it is a group of shapes
                If Not gi Is Nothing Then
                    If oShape.GroupItems.Count > 0 Then
                        For i = 0 To oShape.GroupItems.Count - 1
                            oShape.GroupItems(i).TextFrame.TextRange.LanguageID = lang
                        Next
                    End If
                'it's none of the above, it's just a simple shape, change the language ID
                Else
                    oShape.TextFrame.TextRange.LanguageID = lang
                End If
            End If
        Next
    Next End Sub

6
2018-05-22 13:36





En plus de la réponse fournie par Mastergalen et pour répondre aux commentaires concernant le nouveau type de texte:

Si vous remarquez que cette langue sera automatiquement modifiée à chaque fois que vous tapez du nouveau texte (ce qui est très ennuyeux), vous devez changer la langue par défaut actuelle pour PowerPoint:

  • assurez-vous que la fenêtre PowerPoint est une fenêtre active
  • dans le Windows Taskbar (oui, en fait pas dans PowerPoint), vérifiez si Language bar est visible,
    • sinon allez à Control Panel > Region and Language > Keyboards and Languages. Cliquez sur Change keybords..., basculer vers Language bar onglet et vérification Docked in the taskbar option. (Cela vient de Win7, donc peut-être un peu différent dans les autres versions).
  • maintenant action clé - dans le Language bar dans la barre des tâches, cliquez sur le code de langue et passez en EN (si vous voulez utiliser l'anglais dans PowerPoint). A partir de maintenant, tout nouveau texte dans PowerPoint sera dans la langue sélectionnée :-)
  • Si vous voulez écrire dans votre langue d'origine, changez-le simplement.

2
2017-07-04 12:52



Oh mon Dieu, pourquoi feraient-ils quelque chose comme ça?! Merci, a travaillé parfaitement. - Thibault D.
Exactement! devrait également être ajouté à la réponse acceptée. - Abdelhafid Madoui
Mais cela change aussi la disposition du clavier, n'est-ce pas? ... Je veux taper du texte en anglais mais je veux vraiment garder ma disposition de clavier en allemand .... - Johannes S.
@JohannesS. Si vous faites un clic droit En dans la barre des tâches et sélectionnez Settings.. vous verrez dans les langues installées allemand (DE) et anglais (en), si vous développez l'anglais, il y aura Keyboards Dans la liste ci-dessous, développez Claviers et ajoutez votre clavier allemand préféré, supprimez probablement l’anglais également. Je ne l'ai pas essayé, mais devrait fonctionner en théorie ;-) - Gas


J'ai fait un complément en 2014 pour moi-même, qui fonctionne toujours bien dans PowerPoint 2016. https://github.com/wobba/officeaddin/releases/tag/v1.0.1

Il analyse les langues utilisées et vous permet de tout changer en une fois, en boucle.

enter image description here


2
2017-10-20 11:42