Question Excel augmente la lettre seulement chaque troisième ligne


Je veux obtenir beaucoup de données de la feuille Sheet1 à la feuille Sheet2 mais quand je tire une commande vers la droite, elle ne devrait augmenter que le "C" à un "D" toutes les trois rangées. Parce que j'ai 3 commandes à tirer à droite et que toutes doivent simplement s'incrémenter de 1 à 3.

A1 ressemble à ceci:

=WENN(Sheet1!C3>0;Sheet1!C$2;"")

B1 comme ceci:

=WENN(Sheet1!C3>0;Sheet1!$A3;"")

C1 comme ceci:

=WENN(Sheet1!C3>0;Sheet1!C3;"")

Quand je le tire à droite, elles changent comme ceci:

=WENN(Sheet1!F3>0;Sheet1!F$2;"")
=WENN(Sheet1!F3>0;Sheet1!$A3;"")
=WENN(Sheet1!F3>0;Sheet1!F3;"")

Mais je veux:

=WENN(Sheet1!D3>0;Sheet1!D$2;"")
=WENN(Sheet1!D3>0;Sheet1!$A3;"")
=WENN(Sheet1!D3>0;Sheet1!D3;"")

J'espère que tu sais ce que je veux dire. Est-ce qu'il y a un moyen de faire ça?


2
2018-04-05 07:28


origine




Réponses:


Vous pouvez utiliser l'utile OFFSET fonction, afin de contrôler de combien vous voulez déplacer une cellule vers la droite.

Puisque vous souhaitez décaler 1 colonne (dans la feuille Sheet1) toutes les 3 colonnes (dans la feuille Sheet2), vous pouvez utiliser la fonction suivante:

=ROUNDUP(COLUMN()/3,0)-1

Cela utilisera essentiellement le numéro de colonne, divisé par 3 et arrondi. Ensuite, nous supprimons 1, car nous ne voulons pas décaler les 3 premières colonnes. Si vous tirez ceci vers la droite, vous obtiendrez la séquence suivante: 0 0 0 1 1 1 2 2 2 3 3 3...

Maintenant, vous savez par combien vous devez déplacer la cellule C3, vous pouvez utiliser le OFFSET fonction pour obtenir les bonnes données. Voici les formules à utiliser dans Sheet2:

A1

=IF(OFFSET(Sheet1!$C3,0,ROUNDUP(COLUMN()/3,0)-1)>0,OFFSET(Sheet1!$C$2,0,ROUNDUP(COLUMN()/3,0)-1),"")

B1

=IF(OFFSET(Sheet1!$C3,0,ROUNDUP(COLUMN()/3,0)-1)>0,Sheet1!$A3,"")

C1

=IF(OFFSET(Sheet1!$C3,0,ROUNDUP(COLUMN()/3,0)-1)>0,OFFSET(Sheet1!$C3,0,ROUNDUP(COLUMN()/3,0)-1),"")

Résultat attendu:

enter image description here


Vous semblez utiliser Excel en allemand. Voici les formules traduites:

=WENN(BEREICH.VERSCHIEBEN(Sheet1!$C3;0;AUFRUNDEN(SPALTE()/3;0)-1)>0;BEREICH.VERSCHIEBEN(Sheet1!$C$2;0;AUFRUNDEN(SPALTE()/3;0)-1);"")
=WENN(BEREICH.VERSCHIEBEN(Sheet1!$C3;0;AUFRUNDEN(SPALTE()/3;0)-1)>0;Sheet1!$A3;"")
=WENN(BEREICH.VERSCHIEBEN(Sheet1!$C3;0;AUFRUNDEN(SPALTE()/3;0)-1)>0;BEREICH.VERSCHIEBEN(Sheet1!$C3;0;AUFRUNDEN(SPALTE()/3;0)-1);"")

1
2018-04-05 10:40